Elroir
Silver Member | Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
AlexLev59
Цитата:| Можно ли программно вычислить, время выполнения командного файла? |
Можно, но код громоздкий получается:
Код:
@echo off
setlocal
for /f "tokens=1-4 delims=:," %%a in ('echo %time%') do call :setTime start %%a %%b %%c %%d
:: ЗДЕСЬ ТВОЙ КОД
:: Вместо строчки ping-a
:: можно написать "call yourBatchFile.cmd"
ping -n 63 127.0.0.1>nul
:: КОНЕЦ ТВОЕГО КОДА
for /f "tokens=1-4 delims=:," %%a in ('echo %time%') do call :setTime finish %%a %%b %%c %%d
call :showTime
goto :EOF
:setTime
set "%1Time=%2:%3:%4,%5"
set "t=%5"
set "s=%4"
set "m=%3"
set "h=%2"
if "%t:~0,1%"=="0" set "t=%t:~1%"
if "%s:~0,1%"=="0" set "s=%s:~1%"
if "%m:~0,1%"=="0" set "m=%m:~1%"
if "%h:~0,1%"=="0" set "h=%h:~1%"
set "tt=%t%"
set /a "ss=s * 100"
set /a "mm=m * 6000"
set /a "hh=h * 360000"
set /a "%1=hh+mm+ss+tt"
goto :EOF
:showTime
set /a "dif=%finish%-%start%"
set /a "difHH=dif / 360000"
set /a "difRem=dif %% 360000"
set /a "difMM=difRem / 6000"
set /a "difRem=difRem %% 6000"
set /a "difSS=difRem / 100"
set /a difTT=difRem %% 100"
set "difference=%difHH%:%difMM%:%difSS%,%difTT%"
echo start = %StartTime%
echo finish = %FinishTime%
echo Time taken : %difference%
|
----------
"В интернете есть все, но не всегда" |
|
