Elroir
Silver Member | Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
stepanovig
Код:
for /f "tokens=*" %%i in ('more^<a.txt') do call :aaa %%i
goto :eof
:aaa
set "a=%*"
set "a=%a:AAAAA=%"
1>>a2.txt echo %a%
|
Добавлено:
gilyo
Например, юзеры Vasya и Petya принадлежат к группе, которой нужны все шары (group1), а юзер Vova к группе, которой нужны только первая и 3-я шары (group2):
Код:
@echo off
setlocal
set "group1=Vasya Petya Ira Sasha"
set "group2=Vova Dima Gena Valya"
:: Проверка первой группы
echo %group1% | find /i "%USERNAME%">nul
if not errorlevel 1 (
%systemroot%\SYSTEM32\net use m: \\D_ser\SCR$
%systemroot%\SYSTEM32\net use f: \\D_ser\SEP$
%systemroot%\SYSTEM32\net use n: \\D_ser\STAT$
goto :EOF
)
:: Проверка второй группы
echo %group2% | find /i "%USERNAME%">nul
if not errorlevel 1 (
%systemroot%\SYSTEM32\net use m: \\D_ser\SCR$
%systemroot%\SYSTEM32\net use n: \\D_ser\STAT$
goto :EOF
)
|
В предыдущем коде, мы для каждой группы указывали шары. Можно сделать по-другому - для каждой шары указывать группу:
Код:
@echo off
setlocal
set "group_for_share1=Vasya Petya Vova"
set "group_for_share2=Vasya Petya"
set "group_for_share3=Vasya Petya Vova"
:: Проверяем первую шару
echo %group_for_share1% | find /i "%USERNAME%">nul
if not errorlevel 1 %systemroot%\SYSTEM32\net use m: \\D_ser\SCR$
:: Проверяем вторую шару
echo %group_for_share2% | find /i "%USERNAME%">nul
if not errorlevel 1 %systemroot%\SYSTEM32\net use f: \\D_ser\SEP$
:: Проверяем третью шару
echo %group_for_share3% | find /i "%USERNAME%">nul
if not errorlevel 1 %systemroot%\SYSTEM32\net use n: \\D_ser\STAT$
|
Добавлено:
tuwkan
Код:
@echo off
:loop
ping 192.168.0.1 | find "TTL=">nul
if not errorlevel 1 (
taskkill /f /im NMNE.exe>nul 2>&1
) else (
tasklist | find /i "nmne.exe">nul
if errorlevel 1 start "" nmne.exe"
)
ping -n 31 -w 1000 127.0.0.1>nul
goto loop
|
После запуска, батник будет каждые 30 секунд делать проверку, пока его не закроют.
Добавлено:
Artem_Butenko
С помощью утилиты cmdow.exe - в самом батнике прописывается на первой строчке:
Код:
При этом, консольное окошко появится на мгновение при запуске батника и исчезнет.
С помощью утилиты hstart.exe - надо запускать батник этой утилитой. При этом, окно батника не появляется вообще:
Код:| hstart /NOCONSOLE "batch_file.cmd" |
Ссылки на обе утилиты можно найти в шапке, в разделе "Полезные утилиты"
----------
"В интернете есть все, но не всегда" |
|
