Задачи на bat-файлах 2 - [82] :: Microsoft Windows :: Компьютерный форум Ru.Board

Вот накропал скриптик для перемепа уже подмепленных дисков для систем 2k-xp.
Смотрит если меп на сервер ,если есть перемепливает на другой на туже букву.
Мож кому пригодится как мне.
Предложения по тюнингу принимаются. Только плиз без сторонних языков.Задача такая.
Да если не сложно у кого мож под рукой подкиньте аналог на английской винде вот этого пути
c:\windows\ГЛАВНО~1\ПРОГРА~1\АВТОЗА~1\

Код:

@echo off
IF "%1" == "" GOTO :ERR
IF "%2" == "" GOTO :ERR
IF %OS%==Windows_NT set key=/persistent:yes
IF exist c:\windows\ГЛАВНО~1\ПРОГРА~1\АВТОЗА~1\null set bat=c:\windows\ГЛАВНО~1\ПРОГРА~1\АВТОЗА~1
IF exist d:\windows\ГЛАВНО~1\ПРОГРА~1\АВТОЗА~1\null set bat=d:\windows\ГЛАВНО~1\ПРОГРА~1\АВТОЗА~1
IF exist e:\windows\ГЛАВНО~1\ПРОГРА~1\АВТОЗА~1\null set bat=e:\windows\ГЛАВНО~1\ПРОГРА~1\АВТОЗА~1
IF %OS%==Windows_NT set bat=%windir%\system32
set newshare=%bat%\newshare.bat
set source=%bat%\list_share.txt
net use >%source%

set oldserver=%1
set newserver=%2

setlocal
echo ::%oldserver%>%newshare%
for %%a in (%newshare%) do set "size=%%~za"
set /a "size=size-4"
set /a "size2=size+3"
echo ::%size% >%newshare%

echo ::Переменные заданы %oldserver% %newserver% >> %newshare%

SetLocal enabledelayedexpansion
for /F "eol=T tokens=1,2,3 skip=6 delims= " %%a in (%source%) DO (
set status=%%a
set status1=!status!
set letter=%%b
set letter1=!letter!
set server=%%c
set server1=!server:~2,%size%!
echo ::"!letter!","%oldserver%","!server1:~0,%size%!","\\%newserver%\!server:~%size2%,10!">>%newshare%

IF /i "%oldserver%" EQU "!server1:~0,%size%!" echo net use !letter! /del /y >>%newshare%
IF /i "%oldserver%" EQU "!server1:~0,%size%!" echo net use !letter! "\\%newserver%\!server:~%size2%,100!" %key% >>%newshare%
)
endlocal

call %newshare%
IF %OS%==Windows_NT del %newshare%

@echo ***********************************************************
@echo * *
@echo * Программа завершила все операции!! *
@echo * Проверьте правильность переключения ресурсов с сервера: *
@echo * %oldserver% на новый сервер %newserver%
@echo * При появлении ошибок обратитесь к администраторам *
@echo * *
@echo ***********************************************************
pause
goto END

:ERR
@echo **********************************************************
@echo * *
@echo * Не передан параметр в программу!!! *
@echo * Парамеры запуска newmap [старый сервер] [новый сервер] *
@echo * Пример:newmap server1 server2 *
@echo * *
@echo **********************************************************
pause
:END

Модерирует : KLASS, IFkO
vu1tur (27-04-2007 11:55): продолжаем в теме «Задачи на bat-файлах 3»	Версия для печати • Подписаться • Добавить в закладки
Страницы: 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100