DarkMasterW
Member | Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
Оказалось возможно по нескольким дискам растащить песочницы, правда, пожалуй, не самый юзер-френдли вариант. Тем не менее ничего экстримально сложного нет.
Вариант 1:
1) Создаем песочницу через стандартный интерфейс.
2) Настроить/Редактировать конфигурацию.
3) В открывшемся файле ищем нашу песочницу (в самом низу).
4) Дописываем желаемый путь:
FileRootPath=НАШ_ПРЕКРАСНЫЙ_ПУТЬ
5) Сохраняем файл.
6) Может дополнительно понадобиться перезагрузить конфигурацию: Настроить/Перезагрузить конфигурацию.
Вариант 2:
1) Запускаем cmd.exe (пуск/выполнить/cmd.exe или win+r/cmd.exe)
2) Вводим:
C:\Program Files\Sandboxie\SbieIni.exe set ИМЯ_СОЗДАВАЕМОЙ_ПЕСОЧНИЦЫ Enabled y
C:\Program Files\Sandboxie\SbieIni.exe set ИМЯ_СОЗДАВАЕМОЙ_ПЕСОЧНИЦЫ FileRootPath НАШ_ПРЕКРАСНЫЙ_ПУТЬ
"C:\Program Files\Sandboxie\Start.exe" /reload
3) При этом служба нормально подхватывает созданную песочницу, можно запустить приложение из мено по ПКМ, либо из папки. Однако в интерфейсе песочница может не прорисоваться. Эффект чисто визуальный. Если ее не видим, то Настроить/Перезагрузить конфигурацию.
Вариант 3:
Написал батник для автоматизации создания песочницы в отдельную папку (можно на другом диске).
Для использования:
1) Создайте текстовый файл и поместите в него данный код.
2) Отредактируйте строку set prefix=%CD% указав путь к папке с новыми пеосчницами, если необходимо.
3) Сохраните, закройте.
4) Смените расширение файла на с .txt на .bat
Код: @echo off
chcp 1251 > nul
:: Папка в которую будут складываться новые песочницы.
:: Путь может быть абсолютным или относительным
:: "\" в конце адреса и кавычки не нужны.
:: Пример путей:
:: e:\box
:: f:\my_folder\box
:: Если нужен отностиельный путь,
:: то поставьте %CD%.
:: set prefix=%CD%
set prefix=%CD%
set "prefix=%prefix:"=%"
if "%prefix:~-1%"=="\" set "prefix=%prefix:~0,-1%"
:input
set /P name=Name of new box:
if exist "%prefix%\%name%" (
echo "%prefix%\%name%" already exist. Input another name.
goto input
)
if "%name%"=="" echo You need input name. & goto :err
set "name=%name:"=?%"
set "allowedChars=0-9A-Za-z"
set "deniedChars=<>&%%()|^№"
if not "%name:~-32%"=="%name%" echo Name is too long& goto :err
echo."%name%"| findstr /r /i "[%deniedChars%]" > nul && (echo Forbidden char. & goto :err)
if errorlevel 1 echo.%name%| findstr /r /c:"[^%allowedChars%]" > nul && (echo Forbidden char. & goto :err)
echo Creating...
:: Создаем новую песочницу.
"C:\Program Files\Sandboxie\SbieIni.exe" set %name% Enabled y
:: Устанавливаем путь для новой песочницы.
:: И часть дефолтных параметров.
:: Прописываемые поумолчанию шаблоны для увелечения безопасности не генерируются.
"C:\Program Files\Sandboxie\SbieIni.exe" set %name% FileRootPath "%prefix%\%name%"
"C:\Program Files\Sandboxie\SbieIni.exe" set %name% ConfigLevel 7
"C:\Program Files\Sandboxie\SbieIni.exe" set %name% BlockNetworkFiles y
"C:\Program Files\Sandboxie\SbieIni.exe" set %name% BorderColor #00FFFF,ttl
"C:\Program Files\Sandboxie\SbieIni.exe" set %name% DropAdminRights y
:: Перезагружаем конфигруацию, чтобы она вступила в силу.
:: (работает только для сервиса, интерфейс не обновится)
"C:\Program Files\Sandboxie\Start.exe" /reload
:: Запускаем cmd.exe внутри новой песочницы, чтобы создались служебные файлы.
"C:\Program Files\Sandboxie\Start.exe" /box:%name% cmd /c
::"C:\Program Files\Sandboxie\Start.exe" mshta "javascript:close();"
::pause
:: Создаем для удобства папки с дисками.
for /f "delims=" %%a in ("%prefix%") do set letter=%%~da
mkdir "%prefix%\%name%\drive\%letter:~0,1%\"
::mkdir "%prefix%\%name%\drive\J\"
:: Перезапускаем интерфейс, чтобы обновить в нем список песочниц.
taskkill /F /IM SbieCtrl.exe > nul
start "" "C:\Program Files\Sandboxie\SbieCtrl.exe"
exit /b
:err
echo You must use only A-Za-z0-9 in name.
echo Dont use spaces and names longer than 32 characters.
goto input
|
|
Всего записей: 284 | Зарегистр. 17-04-2010 | Отправлено: 22:32 28-12-2018 | Исправлено: DarkMasterW, 18:45 15-01-2019 |
|
Варезник » Sandboxie
