insorg
Platinum Member | Редактировать | Профиль | Сообщение | Цитировать | Сообщить модератору
harrykkk
Цитата:| Может как случайно поломали, так случайно и починят |
Даю 98% что "случайно" и будет. Причём либо в ближайших версиях, либо спустя десяток.
Цитата:Скажем так, теперь он точно стал бесполезен. Это раньше на всяких ADSL или где-то в селе на отшибе проще было подгрузить что-то из кеша, чем грузить сеть. Теперь же при засилье всяких бесконечно-прокруточных страниц и прочего js-говна листать кеши вообще бесполезно, а иногда вообще вредно. И я не вижу никакой рациональной причины оставлять весь этот лишний кеше-мусор на винте/ssd.
WatsonRus
Цитата:| мне вот заглушки бесполезны |
А для меня бесполезно всё то, что этими заглушками я и прибил. Тем более оно способно накапливаться на несколько ГБ. Каждому своё.
harrykkk
Цитата:| А можно ли этот браузер установить как обычную программу в "C:\Program Files" |
Цитата:| Там есть еще ссылка Installer. Никогда не пользовался |
Я тоже никогда не пользовался установками хромоклонов. Потому что оно не надо при наличии вот такого батника (закинуть в папку к ехе браузера и запустить от админа). Естественно, если имя ехе отличается от указанных у меня, можно добавить в указанное место строку (по аналогии с предыдущей) со своим именем ехе.
DefaultBrowserChrome.bat - установка распакованного (портабле) хрома в список программ по умолчанию (равноценно обычной установке, но надёжнее и без лишнего мусора в системе)
Код: @ECHO off
title Default browser changer for Windows 7...11
cd "%~dp0"
SET "BrowserFileName=Chrome"
if exist "Opera.exe" @set "BrowserFileName=Opera"
if exist "Kinza.exe" @set "BrowserFileName=Kinza"
if exist "vivaldi.exe" @set "BrowserFileName=vivaldi"
:: if exist "напиши своё имя и убери двоеточие в начале.exe" @set "BrowserFileName=напиши своё имя и убери двоеточие в начале"
SET "BrowserDescr=%BrowserFileName% with custom tweaks"
SET "BrowserFullPath=%~dp0%BrowserFileName%.exe"
SET "BrowserIcon=\"%BrowserFullPath%\",0"
SET "BrowserConfig1=--aggressive-cache-discard --disable-cache --disable-application-cache --disable-offline-load-stale-cache --disable-gpu-program-cache --disable-gpu-shader-disk-cache --disk-cache-dir=nul --disk-cache-size=1 --media-cache-size=1"
SET "BrowserConfig2=--disable-background-networking --no-default-browser-check"
SET "BrowserArgs=\"%BrowserFullPath%\" %BrowserConfig1% %BrowserConfig2% -- \"%%1\""
if not exist "%BrowserFullPath%" (ECHO ERROR: "%BrowserFullPath%" not found. &pause &exit)
ECHO "%BrowserFullPath%" found.
reg add HKEY_LOCAL_MACHINE /f>nul 2>&1
if ERRORLEVEL 1 (ECHO ERROR: you have no privileges. &pause &goto NOADMIN)
set DeletePaths=N
set /p DeletePaths=Delete registry paths? [Y/N]
if /i "%DeletePaths%"=="Y" (
ECHO Delete registry paths
reg delete "HKEY_LOCAL_MACHINE\Software\Classes\%BrowserFileName%HTML" /f
reg delete "HKEY_LOCAL_MACHINE\Software\RegisteredApplications" /v "%BrowserFileName%" /f
reg delete "HKEY_LOCAL_MACHINE\Software\Clients\StartMenuInternet\%BrowserFileName%" /f
)
set RegApsCaps=N
set /p RegApsCaps=Write RegisteredApplications, Capabilities? [Y/N]
if /i "%RegApsCaps%"=="Y" (
ECHO RegisteredApplications Capabilities
reg add "HKEY_LOCAL_MACHINE\Software\Classes\%BrowserFileName%HTML" /v "" /t REG_SZ /d "%BrowserFileName% Document" /f
reg add "HKEY_LOCAL_MACHINE\Software\Classes\%BrowserFileName%HTML\DefaultIcon" /v "" /t REG_SZ /d "%BrowserIcon%" /f
reg add "HKEY_LOCAL_MACHINE\Software\Classes\%BrowserFileName%HTML\shell\open\command" /v "" /t REG_SZ /d "%BrowserArgs%" /f
reg add "HKEY_LOCAL_MACHINE\Software\Classes\%BrowserFileName%URL" /v "" /t REG_SZ /d "%BrowserFileName% Protocol" /f
reg add "HKEY_LOCAL_MACHINE\Software\Classes\%BrowserFileName%URL" /v "EditFlags" /t REG_DWORD /d "2" /f
reg add "HKEY_LOCAL_MACHINE\Software\Classes\%BrowserFileName%URL" /v "FriendlyTypeName" /t REG_SZ /d "%BrowserFileName% Protocol" /f
reg add "HKEY_LOCAL_MACHINE\Software\Classes\%BrowserFileName%URL" /v "URL Protocol" /t REG_SZ /d "" /f
reg add "HKEY_LOCAL_MACHINE\Software\Classes\%BrowserFileName%URL\DefaultIcon" /v "" /t REG_SZ /d "%BrowserIcon%" /f
reg add "HKEY_LOCAL_MACHINE\Software\Classes\%BrowserFileName%URL\shell\open\command" /v "" /t REG_SZ /d "%BrowserArgs%" /f
reg add "HKEY_LOCAL_MACHINE\Software\Clients\StartMenuInternet\%BrowserFileName%" /v "" /t REG_SZ /d "%BrowserFileName%" /f
reg add "HKEY_LOCAL_MACHINE\Software\Clients\StartMenuInternet\%BrowserFileName%\Capabilities" /v "ApplicationDescription" /t REG_SZ /d "%BrowserDescr%" /f
reg add "HKEY_LOCAL_MACHINE\Software\Clients\StartMenuInternet\%BrowserFileName%\Capabilities" /v "ApplicationIcon" /t REG_SZ /d "%BrowserIcon%" /f
reg add "HKEY_LOCAL_MACHINE\Software\Clients\StartMenuInternet\%BrowserFileName%\Capabilities" /v "ApplicationName" /t REG_SZ /d "%BrowserFileName%" /f
reg add "HKEY_LOCAL_MACHINE\Software\Clients\StartMenuInternet\%BrowserFileName%\Capabilities\FileAssociations" /v ".htm" /t REG_SZ /d "%BrowserFileName%HTML" /f
reg add "HKEY_LOCAL_MACHINE\Software\Clients\StartMenuInternet\%BrowserFileName%\Capabilities\FileAssociations" /v ".html" /t REG_SZ /d "%BrowserFileName%HTML" /f
reg add "HKEY_LOCAL_MACHINE\Software\Clients\StartMenuInternet\%BrowserFileName%\Capabilities\StartMenu" /v "StartMenuInternet" /t REG_SZ /d "%BrowserFileName%" /f
reg add "HKEY_LOCAL_MACHINE\Software\Clients\StartMenuInternet\%BrowserFileName%\Capabilities\URLAssociations" /v "http" /t REG_SZ /d "%BrowserFileName%URL" /f
reg add "HKEY_LOCAL_MACHINE\Software\Clients\StartMenuInternet\%BrowserFileName%\Capabilities\URLAssociations" /v "https" /t REG_SZ /d "%BrowserFileName%URL" /f
reg add "HKEY_LOCAL_MACHINE\Software\Clients\StartMenuInternet\%BrowserFileName%\DefaultIcon" /v "" /t REG_SZ /d "%BrowserIcon%" /f
reg add "HKEY_LOCAL_MACHINE\Software\Clients\StartMenuInternet\%BrowserFileName%\InstallInfo" /v "IconsVisible" /t REG_DWORD /d "1" /f
reg add "HKEY_LOCAL_MACHINE\Software\Clients\StartMenuInternet\%BrowserFileName%\shell\open\command" /v "" /t REG_SZ /d "\"%BrowserFullPath%\"" /f
reg add "HKEY_LOCAL_MACHINE\Software\RegisteredApplications" /v "%BrowserFileName%" /t REG_SZ /d "Software\Clients\StartMenuInternet\%BrowserFileName%\Capabilities" /f
)
goto FIN
:NOADMIN
:: reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\Shell\Associations\UrlAssociations\http\UserChoice" /v "Progid" /t REG_SZ /d "%BrowserFileName%URL" /f
:: reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\Shell\Associations\UrlAssociations\https\UserChoice" /v "Progid" /t REG_SZ /d "%BrowserFileName%URL" /f
:: убери двоеточния, чтобы назначить браузером по умолчанию для текущего пользователя
:FIN
"%windir%\system32\control.exe" /name Microsoft.DefaultPrograms /page pageDefaultProgram
@pause |
Примечания!
Крайне желательно отсутствие не-ANSI символов в пути браузера. На всякий случай.
Строки с указанием BrowserConfig1 и BrowserConfig2 можно закомментировать двумя двоеточиями в случае если она не нужна, либо редактировать на своё усмотрение.
--disable-background-networking - не только не даст хромому гадить посторонним трафиком в фоне, но и запретит ему обновлять расширения. Если их автообнова нужна - ключ убрать.
--no-default-browser-check - подстраховка, чтобы браузер не потёр нашу конфигу и не задублировал себя в виндовом списке программ. Удалять не нужно. Если вдруг назначил что-то другое стандартным браузером, то для "вернуть взад" просто запустить батник из папки с ехе браузера ещё раз.
Ответы на вопрос "Delete registry paths?" - Y (да) или N (нет). На случай uninstallа браузера. Y - этот браузер будет удалён из списка программ по умолчанию. N - продолжаем работу батника.
Ответы на вопрос "Write RegisteredApplications, Capabilities?" - Y (да) или N (нет). Y - прописываем браузер в список программ по умолчанию. N - пропускаем этот шаг.
Батник накидан на скорую руку, свою задачу выполняет исправно, хотя и можно было бы чуть причесать иначе. Или разделить на два - install и uninstall отдельные. Но так проще, ибо потерять сложнее. Ну, и если что-то вдруг пошло не так, то все записи в реестр (а делаются только они) на виду и их можно удалить даже вручную.
|
Всего записей: 18647 | Зарегистр. 04-11-2010 | Отправлено: 08:57 02-08-2021 | Исправлено: insorg, 09:11 02-08-2021 |
|
